a5e7c48f70
* Updated package.json (and made an excuse to make a branch) * Video filepath parser (#6) * Restructured files; Added parser placeholder * More restructuring * Added basic parser for hydrating template strings * Improved docs * More docs * Initial implementation of media profiles (#7) * [WIP] Added basic video download method * [WIP] Very-WIP first steps at parsing options and downloading * Made my options safe by default and removed special safe versions * Ran html generator for mediaprofile model - leaving as-is for now * Addressed a bunch of TODO comments * Add "channel" type Media Source (#8) * [WIP] Working on fetching channel metadata in yt-dlp backend * Finished first draft of methods to do with querying channels * Renamed CommandRunnerMock to have a more descriptive name * Ran the phx generator for the channel model * Renamed Downloader namespace to MediaClient * [WIP] saving before attempting LiveView * LiveView did not work out but here's a working controller how about * Index a channel (#9) * Ran a MediaItem generator; Reformatted to my liking * [WIP] added basic index function * setup oban * Added basic Oban job for indexing * Added in workers for indexing; hooked them into record creation flow * Added a task model with a phx generator * Tied together tasks with jobs and channels * Download indexed videos (#10) * Clarified documentation * more comments * [WIP] hooked up basic video downloading; starting work on metadata * Added metadata model and parsing Adding the metadata model made me realize that, in many cases, yt-dlp returns undesired input in stdout, breaking parsing. In order to get the metadata model working, I had to change the way in which the app interacts with yt-dlp. Now, output is written as a file to disk which is immediately re-read and returned. * Added tests for video download worker * Hooked up video downloading to the channel indexing pipeline * Adds tasks for media items * Updated video metadata parser to extract the title * Ran linting
45 lines
1.5 KiB
Elixir
45 lines
1.5 KiB
Elixir
defmodule Pinchflat.MediaClient.Backends.YtDlp.ChannelTest do
|
|
use ExUnit.Case, async: true
|
|
import Mox
|
|
|
|
alias Pinchflat.MediaClient.ChannelDetails
|
|
alias Pinchflat.MediaClient.Backends.YtDlp.Channel
|
|
|
|
@channel_url "https://www.youtube.com/c/TheUselessTrials"
|
|
|
|
setup :verify_on_exit!
|
|
|
|
describe "get_channel_details/1" do
|
|
test "it returns a %ChannelDetails{} with data on success" do
|
|
expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot ->
|
|
{:ok, "{\"channel\": \"TheUselessTrials\", \"channel_id\": \"UCQH2\"}"}
|
|
end)
|
|
|
|
assert {:ok, res} = Channel.get_channel_details(@channel_url)
|
|
assert %ChannelDetails{id: "UCQH2", name: "TheUselessTrials"} = res
|
|
end
|
|
|
|
test "it passes the expected args to the backend runner" do
|
|
expect(YtDlpRunnerMock, :run, fn @channel_url, opts, ot ->
|
|
assert opts == [playlist_end: 1]
|
|
assert ot == "%(.{channel,channel_id})j"
|
|
|
|
{:ok, "{}"}
|
|
end)
|
|
|
|
assert {:ok, _} = Channel.get_channel_details(@channel_url)
|
|
end
|
|
|
|
test "it returns an error if the runner returns an error" do
|
|
expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot -> {:error, "Big issue", 1} end)
|
|
|
|
assert {:error, "Big issue", 1} = Channel.get_channel_details(@channel_url)
|
|
end
|
|
|
|
test "it returns an error if the output is not JSON" do
|
|
expect(YtDlpRunnerMock, :run, fn _url, _opts, _ot -> {:ok, "Not JSON"} end)
|
|
|
|
assert {:error, %Jason.DecodeError{}} = Channel.get_channel_details(@channel_url)
|
|
end
|
|
end
|
|
end
|